cmake_minimum_required(VERSION 3.11)

project(sj4)

option(SJ4_GLOBAL "Use global variables or not" OFF)
option(SJ4_EMBED "Embed main dictionary or not" OFF)
option(SJ4_EMBED_PLUS "Embed pubdic+ as main dictionary or not" OFF)
option(SJ4_NO_UNICODE "Remove Unicode code completely" OFF)
option(SJ4_BUILD_ONLY_LIB "Always build only library" OFF)
option(SJ4_BUILD_TOOLS "Always build tools" OFF)
option(SJ4_NO_TESTS "Build no tests" OFF)

macro(sj4_library name)
	file(GLOB_RECURSE ${name}_SRCS lib/${name}/**.c)
	add_library(${name} STATIC ${${name}_SRCS})
	target_include_directories(${name} PUBLIC include/${name})
	if(NOT "${name}" STREQUAL "sj4common")
		target_link_libraries(${name} PUBLIC sj4common)
	endif()
endmacro()

sj4_library(sj4common)

sj4_library(sj4charset)
if(NOT SJ4_NO_UNICODE)
	target_compile_definitions(sj4charset PRIVATE UCS)
endif()

sj4_library(sj4core)
if(SJ4_GLOBAL)
	target_compile_definitions(sj4core PUBLIC SJ4_GLOBAL)
endif()
if(SJ4_EMBED_PLUS)
	target_compile_definitions(sj4core PUBLIC EMBED_PLUS)
elseif(SJ4_EMBED)
	target_compile_definitions(sj4core PUBLIC EMBED)
endif()

sj4_library(sj4rkcv)

if(NOT SJ4_GLOBAL)
	sj4_library(sj4lib)
	target_link_libraries(sj4lib PUBLIC sj4core sj4charset)
	if(NOT SJ4_NO_UNICODE)
		target_compile_definitions(sj4lib PRIVATE UCS)
	endif()
endif()

if(NOT SJ4_GLOBAL)
	sj4_library(sj4ime)
	target_link_libraries(sj4ime PUBLIC sj4lib)
endif()

if(SJ4_BUILD_TOOLS OR (NOT CMAKE_BINARY_DIR MATCHES CMAKE_CURRENT_SOURCE_DIR AND NOT SJ4_BUILD_ONLY_LIB))
	file(GLOB_RECURSE SJ4MKDIC_SRCS src/sj4mkdic/**.c)
	add_executable(sj4mkdic ${SJ4MKDIC_SRCS})
	target_include_directories(sj4mkdic PRIVATE include/sj4core)
	target_compile_definitions(sj4mkdic PRIVATE ENGLISH)
	target_link_libraries(sj4mkdic PRIVATE sj4common sj4charset)
	if(NOT SJ4_NO_UNICODE)
		target_compile_definitions(sj4mkdic PRIVATE UTF8)
	endif()

	if(NOT SJ4_GLOBAL AND NOT SJ4_NO_TESTS)
		macro(sj4_test name)
			file(GLOB_RECURSE ${name}_SRCS src/${name}/**.c)
			add_executable(${name} ${${name}_SRCS})
		endmacro()

		sj4_test(sj4test)
		target_link_libraries(sj4test PRIVATE sj4lib)

		sj4_test(sj4test2)
		target_link_libraries(sj4test2 PRIVATE sj4ime)
	endif()
endif()
