# Copyright 2026 Shin'ya Minazuki
EAPI=8

DESCRIPTION="Environment used by Shin'ya Minazuki based on WindowMaker"
HOMEPAGE="https://laidback.moe/~shinyoukai/"

LICENSE="metapackage"
SLOT="0"
KEYWORDS="amd64 arm arm64 x86"

IUSE="+display-manager +dockapps file-manager fonts ime terminal-emulator themes"

DEPEND="
	x11-wm/windowmaker
	display-manager? (
		|| (
			x11-misc/lightdm[gtk]
			x11-misc/slim[pam]
			x11-misc/wdm
		)
	)
	dockapps? (
		x11-plugins/wmamixer
		x11-plugins/wmbattery
		x11-plugins/wmclock
		x11-plugins/wmnd
		x11-plugins/wmsystemtray
	)
	file-manager? (
		|| (
			app-misc/gentoo
			x11-misc/pcmanfm
			x11-misc/xfe
		)
	)
	fonts? (
		media-fonts/arphicfonts
		media-fonts/nanum
		media-fonts/spleen
		media-fonts/twemoji
		media-fonts/umefont
	)
	ime? ( app-i18n/ibus )
	terminal-emulator? (
		|| (
			x11-terms/sakura
			x11-terms/st
			x11-terms/xterm
		)
	)
	themes? ( x11-themes/windowmaker-themes )
"
RDEPEND="${DEPEND}"

pkg_postinst() {
	if has_version '>=x11-misc/slim-1.4.0' || has_version '>=x11-misc/wdm-1.28'; then
		einfo "You may have to create an .xsessionrc script inside your home directory and make it executable"
		einfo "Or configure the display manager to launch available sessions"
	fi
}