# Copyright 2026 Shin'ya Minzazuki
EAPI=8

inherit dune multiprocessing

DESCRIPTION="Minimal HTTP server with a small request router"
HOMEPAGE="
	https://github.com/c-cube/tiny_httpd
	https://opam.ocaml.org/packages/tiny_httpd
"
SRC_URI="https://github.com/c-cube/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0/${PV}"
# Use stable keyword: www-apps/kosuzu now depends on it
KEYWORDS="amd64"
IUSE="camlzip ocamlopt test"

RDEPEND="
	dev-ml/hmap:=
	dev-ml/iostream:=[ocamlopt?]
	dev-ml/logs:=[ocamlopt?]
	dev-ml/result:=[ocamlopt?]
	camlzip? ( >=dev-ml/camlzip-1.06:=[ocamlopt?] )
"
DEPEND="
	${RDEPEND}
	test? (
		dev-ml/qtest
		dev-ml/ounit2
		dev-ml/ptime
		dev-ml/qcheck
		net-misc/curl
	)
"

RESTRICT="!test? ( test ) mirror"
REQUIRED_USE="test? ( camlzip )"

PATCHES=(
	${FILESDIR}/${P}-noseq.patch
)

src_compile() {
	local pkgs="tiny_httpd"
	use camlzip && pkgs="${pkgs},tiny_httpd_camlzip"
	dune build -p "${pkgs}" -j $(get_makeopts_jobs) || die
}

src_install() {
	dune_src_install tiny_httpd
	use camlzip && dune_src_install "tiny_httpd_camlzip"
}